/*
  Copyright (C) 2013 Jolla Ltd.
  Contact: Thomas Perl <thomas.perl@jollamobile.com>
  All rights reserved.

  You may use this file under the terms of BSD license as follows:

  Redistribution and use in source and binary forms, with or without
  modification, are permitted provided that the following conditions are met:
    * Redistributions of source code must retain the above copyright
      notice, this list of conditions and the following disclaimer.
    * Redistributions in binary form must reproduce the above copyright
      notice, this list of conditions and the following disclaimer in the
      documentation and/or other materials provided with the distribution.
    * Neither the name of the Jolla Ltd nor the
      names of its contributors may be used to endorse or promote products
      derived from this software without specific prior written permission.

  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
  ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR
  ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

import QtQuick 2.0
import Sailfish.Silica 1.0
import Pw.Unitoo.Backend 1.0

Page {
    id: timerPage

    allowedOrientations: Orientation.Portrait

    SilicaFlickable {
        anchors.fill: parent

        // PullDownMenu and PushUpMenu must be declared in SilicaFlickable, SilicaListView or SilicaGridView
        PullDownMenu {
            MenuItem {
                text: qsTr("About")
                onClicked: pageStack.push(Qt.resolvedUrl("AboutPage.qml"))
            }

            MenuItem {
                text: qsTr("Settings")
                onClicked: {
                    boxingTimer.status = BoxingTimer.Pause

                    pageStack.push(Qt.resolvedUrl("SettingsPage.qml"))
                }
            }
        }

        PushUpMenu {
            MenuItem {
                text: qsTr("Stop")
                onClicked: boxingTimer.status = BoxingTimer.Stop
            }
            MenuItem {
                text: qsTr("Reset")
                onClicked: boxingTimer.status = BoxingTimer.Reset
            }
        }

        contentHeight: column.height

        Column {
            id: column

            width: timerPage.width
            spacing: Theme.paddingLarge

            PageHeader { title: qsTr("Boxing timer") }
            SectionHeader { text: boxingTimer.preset }

            Label {
                id: labelTimer

                width: parent.width
                horizontalAlignment: Text.AlignHCenter

                font.pixelSize: 244
                text: boxingTimer.remainingTimeToString
                color: boxingTimer.status == BoxingTimer.Rest ? Theme.secondaryColor : Theme.primaryColor
            }

            Button {
                text: boxingTimer.isActive ? qsTr("Pause") : qsTr("Start")

                width: Theme.buttonWidthMedium
                anchors.horizontalCenter: parent.horizontalCenter

                onClicked: {
                    if (boxingTimer.isActive) {
                        boxingTimer.status = BoxingTimer.Pause
                    } else {
                        boxingTimer.restore()
                    }
                }
            }

            SectionHeader {
                text: qsTr("Round")
            }

            Label {
                id: roundLabel

                width: parent.width
                horizontalAlignment: Text.AlignHCenter

                font.pixelSize: 196
                text: boxingTimer.roundsToString
            }
        }
    }
}