mirror of
https://github.com/pachli/pachli-android.git
synced 2025-01-07 14:21:17 +01:00
e41722e16f
Move `ListsActivity`, along with fragments and viewmodels, to a new `feature:lists` module. Previous code used the `item_follow_request` layout, which was not ideal, so update it to use a dedicated layout, `item_account_in_list`. The UI uses strings and views originally defined in the main app, so move them elsewhere so they can be re-used. - `BackgroundMessageView` moves to `core.ui`. - `Lazy` moves to `core.common`. - `ThrowableExtensions` split; the extensions specific to throwables from network activity move to `core.network`, others move to `core.ui`. - `BindingHolder` moves to `core.ui` - Shared drawables and strings move to `core.ui`.
72 lines
1.8 KiB
Plaintext
72 lines
1.8 KiB
Plaintext
pluginManagement {
|
|
repositories {
|
|
google {
|
|
content {
|
|
includeGroupByRegex("com\\.android.*")
|
|
includeGroupByRegex("com\\.google.*")
|
|
includeGroupByRegex("androidx.*")
|
|
}
|
|
}
|
|
gradlePluginPortal()
|
|
}
|
|
|
|
includeBuild("build-logic")
|
|
includeBuild("plugins/markdown2resource")
|
|
}
|
|
|
|
dependencyResolutionManagement {
|
|
repositoriesMode = RepositoriesMode.FAIL_ON_PROJECT_REPOS
|
|
repositories {
|
|
google {
|
|
content {
|
|
includeGroupByRegex("com\\.android.*")
|
|
includeGroupByRegex("com\\.google.*")
|
|
includeGroupByRegex("androidx.*")
|
|
}
|
|
}
|
|
mavenCentral()
|
|
maven("https://jitpack.io")
|
|
}
|
|
}
|
|
|
|
plugins {
|
|
id("com.gradle.enterprise") version "3.16.2"
|
|
}
|
|
|
|
val isCiBuild = !System.getenv("CI").isNullOrBlank()
|
|
|
|
gradleEnterprise {
|
|
buildScan {
|
|
termsOfServiceUrl = "https://gradle.com/terms-of-service"
|
|
termsOfServiceAgree = "yes"
|
|
isUploadInBackground = !isCiBuild
|
|
tag(if (isCiBuild) "CI" else "Local")
|
|
publishAlwaysIf(isCiBuild)
|
|
}
|
|
}
|
|
|
|
enableFeaturePreview("STABLE_CONFIGURATION_CACHE")
|
|
enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")
|
|
|
|
rootProject.name = "pachli-android"
|
|
|
|
include(":app")
|
|
include(":core:accounts")
|
|
include(":core:activity")
|
|
include(":core:common")
|
|
include(":core:data")
|
|
include(":core:database")
|
|
include(":core:designsystem")
|
|
include(":core:preferences")
|
|
include(":core:navigation")
|
|
include(":core:network")
|
|
include(":core:testing")
|
|
include(":core:ui")
|
|
include(":feature:about")
|
|
include(":feature:lists")
|
|
include(":feature:login")
|
|
include(":tools:mklanguages")
|
|
include(":tools:mkserverversions")
|
|
include(":tools:mvstring")
|
|
include(":checks")
|