65a20d8c1b
/: Sync from GCC: 2010-09-30 Michael Eager <eager@eagercon.com> * configure.ac (microblaze): Add target-libssp to noconfigdirs. * configure: Regenerate. 2010-09-21 Iain Sandoe <iains@gcc.gnu.org> * configure.ac (enable-lto): Add Darwin to the list of supported lto targets and amend comment. * configure: Regenerate. 2010-09-03 Jack Howarth <howarth@bromo.med.uc.edu> * configure.ac: Enable LTO by default on Darwin. * configure: Regenerate. 2010-07-23 Marc Glisse <marc.glisse@normalesup.org> PR bootstrap/44455 * configure.ac (extra_mpfr_configure_flags): Copy from extra_mpc_gmp_configure_flags. * configure: Re-generated. config/: Sync from GCC: 2010-09-10 Jonathan Yong <jon_y@users.sourceforge.net> * dfp.m4: Enable decimal float for i?86 cygwin and mingw, and for x86_64 mingw.
57 lines
1.4 KiB
Plaintext
57 lines
1.4 KiB
Plaintext
dnl @synopsis GCC_AC_ENABLE_DECIMAL_FLOAT([target triplet])
|
|
dnl
|
|
dnl Enable C extension for decimal float if target supports it.
|
|
dnl
|
|
dnl @author Andreas Krebbel <Andreas.Krebbel@de.ibm.com>
|
|
|
|
AC_DEFUN([GCC_AC_ENABLE_DECIMAL_FLOAT],
|
|
[
|
|
AC_ARG_ENABLE(decimal-float,
|
|
[ --enable-decimal-float={no,yes,bid,dpd}
|
|
enable decimal float extension to C. Selecting 'bid'
|
|
or 'dpd' choses which decimal floating point format
|
|
to use],
|
|
[
|
|
case $enable_decimal_float in
|
|
yes | no | bid | dpd) default_decimal_float=$enable_decimal_float ;;
|
|
*) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
|
|
Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
|
|
esac
|
|
],
|
|
[
|
|
case $1 in
|
|
powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux* | s390*-*-linux* | \
|
|
i?86*-*-mingw* | x86_64*-*-mingw* | \
|
|
i?86*-*-cygwin*)
|
|
enable_decimal_float=yes
|
|
;;
|
|
*)
|
|
AC_MSG_WARN([decimal float is not supported for this target, ignored])
|
|
enable_decimal_float=no
|
|
;;
|
|
esac
|
|
])
|
|
|
|
# x86's use BID format instead of DPD
|
|
case x$enable_decimal_float in
|
|
xyes)
|
|
case $1 in
|
|
i?86*-*-* | x86_64*-*-*)
|
|
enable_decimal_float=bid
|
|
;;
|
|
*)
|
|
enable_decimal_float=dpd
|
|
;;
|
|
esac
|
|
default_decimal_float=$enable_decimal_float
|
|
;;
|
|
xno)
|
|
# ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
|
|
# dependency on libdecnumber.
|
|
default_decimal_float=dpd
|
|
;;
|
|
esac
|
|
AC_SUBST(enable_decimal_float)
|
|
|
|
])
|