// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    apply from: 'dependencies.gradle'

    ext.bootstrap = [
            kotlinModule : "${project.rootDir}/gradle_scripts/kotlin-module-bootstrap.gradle",
            androidModule : "${project.rootDir}/gradle_scripts/android-module-bootstrap.gradle"
    ]

    repositories {
        google()
        mavenCentral()
        maven { url "https://plugins.gradle.org/m2/" }
    }
    dependencies {
        classpath gradlePlugins.gradle
        classpath gradlePlugins.kotlin
        classpath gradlePlugins.ktlintGradle
        classpath gradlePlugins.detekt
        classpath gradlePlugins.jacoco
    }
}

allprojects {
    // Buildscript here is required by detekt
    buildscript {
        repositories {
            mavenCentral()
            google()
        }
    }

    repositories {
        mavenCentral()
        google()
        maven { url 'https://jitpack.io' }
    }

    // Set Kotlin JVM target to the same for all subprojects
    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
        kotlinOptions {
            jvmTarget = "1.8"
        }
    }
}

apply from: 'gradle_scripts/jacoco.gradle'

wrapper {
    gradleVersion(versions.gradle)
    distributionType("all")
}
