apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: 'kotlin-parcelize'

android {
    compileSdkVersion rootProject.ext.compileSdkVersion

    defaultConfig {
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion
        buildToolsVersion rootProject.ext.buildToolsVersion

        javaCompileOptions {
            annotationProcessorOptions {
                arguments = [
                        "room.incremental"   : "true",
                        "room.schemaLocation": "$projectDir/schemas".toString()
                ]
            }
        }

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles 'consumer-rules.pro'
    }

    sourceSets {
        androidTest.assets.srcDirs += files("$projectDir/schemas".toString())
    }


    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }

        debug {
            minifyEnabled false
            testCoverageEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
    kotlinOptions {
        jvmTarget = '17'
    }
    lint {
        abortOnError false
    }
    namespace 'com.readrops.db'
}

// Needed for kapt starting with kotlin plugin 1.5
kapt {
    arguments {
        arg("room.schemaLocation", "$projectDir/schemas".toString())
        arg("room.incremental", "true")
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    api "androidx.core:core-ktx:1.6.0"
    api 'androidx.appcompat:appcompat:1.3.0'
    api "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"

    testImplementation 'junit:junit:4.13'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test:runner:1.4.0'
    androidTestImplementation 'androidx.test:rules:1.4.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'

    implementation(libs.bundles.room)
    kapt(libs.room.compiler)
    androidTestImplementation(libs.room.testing)

    implementation 'com.github.MatrixDev.Roomigrant:RoomigrantLib:0.3.4' //TODO delete
    kapt 'com.github.MatrixDev.Roomigrant:RoomigrantCompiler:0.3.4'

    implementation(libs.bundles.paging)

    api 'joda-time:joda-time:2.10.10' //TODO replace with java.time?

    implementation(libs.bundles.koin)
    testImplementation(libs.bundles.kointest)

    implementation(libs.bundles.coroutines)
    androidTestImplementation(libs.coroutines.test)
}
